Computations - SR

Reducing the task by solving a linear system

Solve[{sr12 == (sr21 + sr22)*s1^2/z, 
        sr22 == (sr11 + sr12 + sr21 + sr22)*s2^2/z}, {sr12, 
        sr22}]

sr11 + sr12 + sr21 + sr22 /. %[[1]] // Factor

Denominator[%]

Solve[{% == 0, s1 == z/(1 - s2), 
        s2 == z/(1 - s1 - s2)}, {s1, s2, z}]

Thus, the smallest singularity of sr is also the smallest singularity of sr11 resp. sr21.

Solving the system for sr11 and sr21

GroebnerBasis[{sr11*(1 - sr21 - s2) - z, 
        sr21*(1 - sr11 - sr21 - s1 - s2) - z, s1*(1 - s2) - z, 
        s2*(1 - s1 - s2) - z}, {sr21, s1, s2, sr11}, {sr21, s1, 
        s2}]

Expand[%[[1]]/z]

F[sr11_, z_] = %;

Finding a common zero of the polynomial and its derivative

GroebnerBasis[{F[sr11, z], 
        D[F[sr11, z], sr11]}, 
{sr11, 
        z}, {sr11}]

Factor[%[[1]]]

NSolve[% == 0, z]

So the smallest singularity must be z0=0.0938166.

z0 = Root[3844 - 40936  # - 412  #^2 + 125  #^3 &, 2]

Expanding around the singularity

Solve[F[sr11, z0] == 0, sr11];

N[%]

s0 = sr11 /. %%[[2]]

N[s0]

So we have the value of sr11 at the singularity. We calculate the expansion of sr11 now:

D[F[sr11, z], {sr11, 2}] /. {sr11 -> s0, z -> z0} // 
      RootReduce

D[F[sr11, z], z] /. {sr11 -> s0, z -> z0} // 
      RootReduce

a = Sqrt[2  z0*%/%%] // RootReduce

N[a]

Then we have sr11~s0 - 
      a (Sqrt[(1 - (z/z0))]).

\(TraditionalForm\`The\ expansion\ of\ sr21\ follows\ at\ \(once : \ 
        sr21~1 - c2 - z0\/s0 - \(\(a\ z0\)\/s0\^2\) \@\((1 - z\/z0)\)\), \ 
    where\ c2\ is\ the\ value\ of\ s2\ at\ z0 . \ 
        The\ expansion\ of\ sr\ follows\ immediately, \ 
    too . \ The\ constant\ coefficient\ is\ \(z0(c1\^2\ b + z0\ s0 + z0\ b)\)\/\(z0\^2 - z0\ c2\^2 - c1\^2\ c2\^2\), 
    the\ coefficient\ of\ \@\((1 - z\/z0)\)\ is\ \(z0(\(-\(\(a\ c1\^2\ z0\)\/s0\^2\)\) - \(a\ z0\^2\)\/s0\^2 - a\ z0)\)\/\(z0\^2 - z0c2\^2 - \(c1\^2\) c2\^2\), \ 
    where\ c1\ is\ the\ value\ of\ s1\ at\ z0\ and\ b\ is\ the\ value\ of\ sr21\ at\ z0 . \ We\ determine\ b, 
    c1\ and\ c2\ first\  - \ 
      we\ use\ Groebner\ bases\ again\ to\ obtain\ exact\ \(\(results\)\(:\)\)\)

GroebnerBasis[{c1*(1 - c2) - z, c2*(1 - c1 - c2) - z, 
        3844 - 40936 z - 412 (z^2) + 125 (z^3)}, {z, c1, c2}]

Factor[%[[1]]]

NSolve[% == 0, c2]

Since s2 is monotonically increasing with a value of 1/3 at 4/27, we know that c2 = 0.121585.

c2 = Root[4 - 32  # - 8  #^2 + 5  #^3 &, 2]

c1 = c2 - c2^2 // RootReduce

b = 1 - c2 - z0/s0 // RootReduce

z0(c1^2*b + z0*s0 + z0*b)/(z0^2 - z0*c2^2 - c1^2*c2^2)//RootReduce

% // N

z0(-a*c1^2*z0/s0^2 - a*z0^2/s0^2 - a*z0)/
  (z0^2 - z0*c2^2 - c1^2*c2^2)//RootReduce

% // N

Now, we readily obtain the constants in our asymptotics:

%%/Gamma[-1/2]*4*Sqrt[Pi] // RootReduce

% // N

1/(4*z0) // RootReduce

% // N